74HC595を使ってArduinoの出力ピンを拡張する方法(8)

// oneByteFastio.no

#include <fastio.h> // FASTIOライブラリのヘッダファイルをインクルード

hc595<2,3,4,1,LSBFIRST> my595; 
// Arduinoに接続したシフトレジスタに、my595という名前をつける。
// 1番目のパラメータは、74HC595のSER端子と接続するArduinoのピンの番号。
// 2番目のパラメータは、74HC595のSRCLK端子と接続するArduinoのピンの番号。
// 3番目のパラメータは  74HC595のRCLK端子と接続するArduinoのピン番号。
// 4番目のパラメータは、カスケード接続する74HC595の個数。
// 5番目のパラメータは、1バイト内のLSBから送出するか、MSBから送出するかの区別。

void setup() 
{
  my595.init(); // 74HC595とそのドライバの初期化
} // setup

void loop() 
{
  static uint8_t cnt=0;

  my595.shiftOut(cnt++); // 74HC595にcntの内容を送信してから、cntをカウントアップする。
  delay(100); // 0.1秒休む
} // loop

// benchDigitalWrite.ino

const int SER  =2; // SER制御用にするピンの番号を宣言
const int SRCLK=3; // SRCLK制御用にするピンの番号を宣言
const int RCLK =4; // RCLK制御用にするピンの番号を宣言

void setup()
{
  Serial.begin(9600); // シリアルポートを9600bpsで開く
  initHc595(); // 74HC595の制御ピン等を初期化
} // setup

void loop()
{
  uint32_t startTime; // 計測開始時刻[ms]
  
  startTime=millis(); // 計測開始時刻を取得
  
  // 10万回データを転送
  for(int i=0; i<10000; i++) { // 1万回ループ
    // 10回0を送信
    outputOneByteLsbFirst(0);
    outputOneByteLsbFirst(1);
    outputOneByteLsbFirst(2);
    outputOneByteLsbFirst(3);
    outputOneByteLsbFirst(4);
    outputOneByteLsbFirst(5);
    outputOneByteLsbFirst(6);
    outputOneByteLsbFirst(7);
    outputOneByteLsbFirst(8);
    outputOneByteLsbFirst(9);
  } // for i

  Serial.println(millis()-startTime); // シリアルポートに計測結果を表示
} // loop

// 74HC595の制御用ピンおよび74HC595を初期化する
void initHc595()
{
  // 74HC595制御用ピンを出力モードにする
  pinMode(SER,OUTPUT);
  pinMode(SRCLK,OUTPUT);
  pinMode(RCLK,OUTPUT);

  // SRCLKとRCLKをLOWにする(これらのピンはデータを送信していない時はLOWであるべき)
  digitalWrite(SRCLK,LOW);
  digitalWrite(RCLK,LOW);

  // 0を送信して74HC595のパラレル出力ピンを全て0にする(74HC595の初期状態を気にしない場合は省略可能)
  outputOneByteLsbFirst(0);
} // initHc595

// LSBからMSBの順に74HC595に1バイトを送信する
void outputOneByteLsbFirst(uint8_t val)
{
  const int DATA_BITS=8; // 送信するデータのビット数

  // シフトレジスタにデータを送信
  for(int i=0; i<DATA_BITS; i++) {
    digitalWrite(SER,(val&1) ? HIGH : LOW); // SERにvalの最下位ビットを出力
    digitalWrite(SRCLK,HIGH); // SRCLKを立ち上げる(この時74HC595がシフト動作)
    digitalWrite(SRCLK,LOW ); // SRCLKを立ち下げる(次にSRCLKを立ち上げるため)
    val>>=1; // valを1ビットだけ右シフト
  } // for i
  
  // ストレージレジスタにデータを転送
  digitalWrite(RCLK,HIGH); // RCLKを立ち上げる(この時に74HC595のシフトレジスタのパラレル出力がストレージレジスタに転送され、74HC595のしパラレル出力端子にデータが出力される)
  digitalWrite(RCLK,LOW ); // RCLKを立ち下げる(次にRCLKを立ち上げるため)
} // outputOnebyteLsbFirst

// benchShiftOut.ino

const int SER  =2; // SER制御用にするピンの番号を宣言
const int SRCLK=3; // SRCLK制御用にするピンの番号を宣言
const int RCLK =4; // RCLK制御用にするピンの番号を宣言

void setup()
{
  Serial.begin(9600); // シリアルポートを9600bpsで開く
  initHc595(); // 74HC595の制御ピン等を初期化
} // setup

void loop()
{
  uint32_t startTime; // 計測開始時刻[ms]
  
  startTime=millis(); // 計測開始時刻を取得
  
  // 10万回データを転送
  for(int i=0; i<10000; i++) { // 1万回ループ
    // 10回0を送信
    outputOneByte(0,LSBFIRST);
    outputOneByte(1,LSBFIRST);
    outputOneByte(2,LSBFIRST);
    outputOneByte(3,LSBFIRST);
    outputOneByte(4,LSBFIRST);
    outputOneByte(5,LSBFIRST);
    outputOneByte(6,LSBFIRST);
    outputOneByte(7,LSBFIRST);
    outputOneByte(8,LSBFIRST);
    outputOneByte(9,LSBFIRST);
  } // for i

  Serial.println(millis()-startTime); // シリアルポートに計測結果を表示
} // loop

// 74HC595の制御用ピンおよび74HC595を初期化する
void initHc595()
{
  // 74HC595制御用ピンを出力モードにする
  pinMode(SER,OUTPUT);
  pinMode(SRCLK,OUTPUT);
  pinMode(RCLK,OUTPUT);

  // SRCLKとRCLKをLOWにする(これらのピンはデータを送信していない時はLOWであるべき)
  digitalWrite(SRCLK,LOW);
  digitalWrite(RCLK,LOW);

  // 0を送信して74HC595のパラレル出力ピンを全て0にする(74HC595の初期状態を気にしない場合は省略可能)
  outputOneByte(0,LSBFIRST);
} // initHc595

// 74HC595に1バイトを送信する。valは送信するデータ。
// bitOrderにLSBFIRSTを指定するとLSBファーストで送信。bitOrderにMSBFIRSTを指定するとMSBファーストで送信。
void outputOneByte(uint8_t val,uint8_t bitOrder)
{
  // シフトレジスタにデータを送信
  shiftOut(SER,SRCLK,bitOrder,val);

  // ストレージレジスタにデータを転送
  digitalWrite(RCLK,HIGH); // RCLKを立ち上げる(この時に74HC595のシフトレジスタのパラレル出力がストレージレジスタに転送され、74HC595のしパラレル出力端子にデータが出力される)
  digitalWrite(RCLK,LOW ); // RCLKを立ち下げる(次にRCLKを立ち上げるため)
} // outputOnebyte 

// benchFastio.ino

#include <fastio.h> // FASTIOライブラリのヘッダファイルをインクルード

hc595<2,3,4,1,LSBFIRST> my595; 
// Arduinoに接続したシフトレジスタに、my595という名前をつける。
// 1番目のパラメータは、74HC595のSER端子と接続するArduinoのピンの番号。
// 2番目のパラメータは、74HC595のSRCLK端子と接続するArduinoのピンの番号。
// 3番目のパラメータは  74HC595のRCLK端子と接続するArduinoのピン番号。
// 4番目のパラメータは、カスケード接続する74HC595の個数。
// 5番目のパラメータは、1バイト内のLSBから送出するか、MSBから送出するかの区別。

void setup() 
{
  Serial.begin(9600); // シリアルポートを9600bpsで開く
  my595.init(); // 74HC595とそのドライバの初期化
} // setup

void loop() 
{
  uint32_t startTime; // 計測開始時刻[ms]
  
  startTime=millis(); // 計測開始時刻を取得
  
  // 10万回データを転送
  for(int i=0; i<10000; i++) { // 1万回ループ
    // 10回0を送信
    my595.shiftOut(0);
    my595.shiftOut(1);
    my595.shiftOut(2);
    my595.shiftOut(3);
    my595.shiftOut(4);
    my595.shiftOut(5);
    my595.shiftOut(6);
    my595.shiftOut(7);
    my595.shiftOut(8);
    my595.shiftOut(9);
  } // for i

  Serial.println(millis()-startTime); // シリアルポートに計測結果を表示
} // loop