「カットオフ周波数」の解説

このページをスマホなどでご覧になる場合は、画面を横長にする方が読みやすくなります。
2021年03月14日 更新。
用語:カットオフ周波数
用語の読み方:カットオフしゅうはすう
同義語・類義語:遮断周波数
このページで解説している他の用語:通過帯域阻止帯域

カットオフ周波数(cutoff frequeny)は、フィルタ回路において、通過帯域と阻止帯域の境目となる周波数の事です。カットオフ周波数は、遮断周波数とも呼ばれます。

フィルタ回路は、特定の周波数帯域の信号のみを通過し、それ以外の周波数帯域の信号を減衰させて、元々の信号から、好ましくない信号成分(ノイズ)を除去するために使われる回路です。

フィルタ回路において、信号を通過する周波数帯域を通過帯域(passband)といい、信号を減衰させる周波数帯域を阻止帯域(stopband)といいます。通過帯域と阻止帯域の境目となる周波数がカットオフ周波数です。

有用な信号成分をなるべく残し、ノイズをなるべく減衰できるフィルタ回路の設計をするためには、フィルタの回路の構成を適切に選択する事と共に、カットオフ周波数を適切に設定する事が重要となります。カットオフ周波数は、フィルタ回路の特性を考える際に、最も重要な指標の一つとなります。

目次

1. より厳密な定義 … 1ページ
2. 1次CRハイパスフィルタ・ローパスフィルタのカットオフ周波数 … 1ページ
3. 通過帯域の平坦部の利得が1倍でない場合 … 1ページ
4. 1次CRローパスフィルタ・ハイパスフィルタのカットオフ周波数を計算するツール … 1ページ
5. 1次CRローパスフィルタ・ハイパスフィルタを設計するツール … 1ページ
広告

1.より厳密な定義

ここで、低い周波数帯域を減衰し、高い周波数帯域を通過するハイパスフィルタを例に挙げて、もう少し詳しく説明します。

フィルタ回路を通過させたい信号と、フィルタ回路で減衰させたい信号の、周波数にあまり差がない場合、図1の青線で示した様な急峻な特性を持ったフィルタ回路を使う事が好ましいです。青線を見ると、カットオフ周波数を境目に、その周波数から少しでも高い周波数の成分は完全に通過させ(利得=1)、境目の周波数から少しでも低い周波数の成分は完全に減衰させる(利得=0)、理想的な特性になっている事が分かります。

図1、阻止帯域と通過帯域とカットオフ周波数の関係
図1、阻止帯域と通過帯域とカットオフ周波数の関係

しかしながら、現実のフィルタ回路では、この様な理想的な特性は得られません。現実のフィルタ回路は、図1の赤線で示した様な、カットオフ周波数の近辺でなだらかになった特性を持っています。

参考:図1の青線で示した様な理想的な特性のフィルタ回路を実際に作る事はできませんが、青線の特性に限りなく近づける事は理論的には可能です。その場合、特性を理想に近づけるほど回路の規模が大きくなります。また、特性を理想に近づけるほど群遅延時間(簡単に言うと、信号が入力されてから出力されるまでの時間)が長くなり、出力信号の遅れが問題になります。無限大の群遅延時間が必要になるため、完全に特性を理想的にする事は不可能です。

この様に、現実のフィルタ回路では通過帯域と阻止帯域の境界があいまいになります。境界があいまいだと、カットオフ周波数も厳密に定義できなくなります。

この様なあいまいさを避けるため、通常は、利得が通過帯域の平坦部の12倍(約0.707倍)になる周波数(デシベル値で表わすと利得が通過帯域の平坦部から3dB低下する周波数)の事を、カットオフ周波数と呼びます。

注1:カットオフ周波数においては、電圧利得は、通過帯域の平坦部の12倍になりますが、電力利得は、通過帯域の平坦部の12倍になります。

注2:図1に示したフィルタ回路では、通過帯域の平坦部の利得が1倍になっていますが、後述する様に、利得が1倍より小さな値を取るフィルタ回路もあります。また、アクティブフィルタの場合は、通過帯域の利得が1倍を超える場合もあります。

2.1次CRハイパスフィルタ・ローパスフィルタのカットオフ周波数

図2は、1次CRハイパスフィルタの回路図です。また図3は、1次CRローパスフィルタの回路図です。

図2、1次CRハイパスフィルタの回路図
図2、1次CRハイパスフィルタの回路図
図3、1次CRローパスフィルタの回路図
図3、1次CRローパスフィルタの回路図

これらの回路のカットオフ周波数は、共に次の式で与えられます。

fc=1CR ・・・ (1)

ここで、fcは1次CRハイパスフィルタおよび1次CRローパスフィルタのカットオフ周波数です。

電子回路の設計をしていると、この式を非常によく使いますので、憶えておくといいでしょう。

例として、C=0.1[μF]、R=1[kΩ]としてカットオフ周波数を計算すると、fc=1.59[kHz]となります。CRがこれらの値の場合に、1次CRハイパスフィルタおよび1次CRローパスフィルタの周波数特性を計算した結果を図4に示しますが、どちらの回路も、確かに1.59kHzの時に利得が-3dBになっている事が確認できます。

図4、1次CRハイパスフィルタ/ローパスフィルタの周波数特性
図4、1次CRハイパスフィルタ/ローパスフィルタの周波数特性

3.通過帯域の平坦部の利得が1倍でない場合

図5に示すのは、通過帯域で減衰が生じるCR1次ハイパスフィルタの一例です。この回路では、通過帯域の平坦部の利得が-6dB(0.5倍)になります。

図5、通過帯域で6dBの減衰が生じるCR1次ハイパスフィルタ
図5、通過帯域で6dBの減衰が生じるCR1次ハイパスフィルタ

C=0.1[μF]、R=1[kΩ]の場合に、図5の回路の周波数特性を計算した結果を図6に示します。この場合のカットオフ周波数は、利得が-9dB(通過帯域の平坦部の利得-6dBからさらに3dB引いた値)になる796Hzです。

図6、C=0.1[μF]、R=1[kΩ]の場合の図5の回路の周波数特性
図6、C=0.1[μF]、R=1[kΩ]の場合の図5の回路の周波数特性
広告

4.1次CRローパスフィルタ・ハイパスフィルタのカットオフ周波数を計算するツール

図2に示す1次CRハイパスフィルタおよび図3に示す1次CRローパスフィルタの共振周波数fcは、共に式(1)で得られます。

図2(再掲)、1次CRハイパスフィルタの回路図
図2(再掲)、1次CRハイパスフィルタの回路図
図3(再掲)、1次CRローパスフィルタの回路図
図3(再掲)、1次CRローパスフィルタの回路図

画面1のツールで、抵抗値Rと静電容量Cから、カットオフ周波数fcを求める事ができます。画面をクリックしてから抵抗値と静電容量を入力してください。数値にはkやMなどの補助単位が使えます。

10 PI=3.141592653589793238
20 PRINT "抵抗値Rと静電容量Cから、CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcを計算します。RとCの値を入力してください。"
30 PRINT
40 INPUT "R[Ω]: ",S$
50 GOSUB 1000
60 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 40
70 R=RESULT
80 INPUT "C[F]: ",S$
90 GOSUB 1000
100 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 80
110 C=RESULT
120 PRINT
130 N=R:GOSUB 2000
140 PRINT "入力されたR: ";RESULT$;"Ω"
150 N=C:GOSUB 2000
160 PRINT "入力されたC: ";RESULT$;"F"
170 FC=1/(2*PI*C*R)
180 N=FC:GOSUB 2000
190 PRINT "fcの計算結果: ";RESULT$;"Hz"
200 PRINT
210 GOTO 20
1000 '入力した文字列を数値に変換
1010 IF S$="" THEN ERR=1:RETURN
1020 IF LEFT$(S$,1)="+" THEN S$=MID$(S$,2)
1030 IF S$="" THEN ERR=1:RETURN
1040 L$=RIGHT$(S$,1)
1050 IF L$="K" OR L$="k" THEN K=1E3 :GOTO 1160
1060 IF L$="M" THEN K=1E6 :GOTO 1160
1070 IF L$="G" OR L$="g" THEN K=1E9 :GOTO 1160
1080 IF L$="T" OR L$="t" THEN K=1E12 :GOTO 1160
1090 IF L$="m" THEN K=1E-3 :GOTO 1160
1100 IF L$="μ" OR L$="u" THEN K=1E-6 :GOTO 1160
1110 IF L$="n" OR L$="N" THEN K=1E-9 :GOTO 1160
1120 IF L$="p" OR L$="P" THEN K=1E-12:GOTO 1160
1130 IF L$="f" OR L$="F" THEN K=1E-15:GOTO 1160
1140 K=1
1150 GOTO 1170
1160 S$=LEFT$(S$,LEN(S$)-1)
1170 IF S$="" THEN ERR=1:RETURN
1180 STAT=0
1190 FOR I=1 TO LEN(S$)
1200 C$=MID$(S$,I,1)
1210 IF STAT=0 THEN IF C$="." THEN STAT=1:GOTO 1310
1220 IF STAT=0 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1230 IF STAT=0 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1240 IF STAT=1 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=2:GOTO 1310
1250 IF STAT=2 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1260 IF STAT=2 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1270 IF STAT=3 THEN IF C$="+" OR C$="-" THEN STAT=4:GOTO 1310
1280 IF STAT=3 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1290 IF STAT=4 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1300 IF STAT=5 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1310 NEXT I
1320 IF (STAT=1)+(STAT=3)+(STAT=4) THEN ERR=1:RETURN
1330 RESULT=VAL(S$)*K
1340 IF RESULT<=1E-20 THEN ERR=1:RETURN
1350 ERR=0:RETURN
2000 '数値を補助単位付きの文字列に変換
2010 IF ABS(N)<1E-12 THEN RESULT$=STR$(N*1E15)+"f":RETURN
2020 IF ABS(N)<1E-9 THEN RESULT$=STR$(N*1E12)+"p":RETURN
2030 IF ABS(N)<1E-6 THEN RESULT$=STR$(N*1E9 )+"n":RETURN
2040 IF ABS(N)<1E-3 THEN RESULT$=STR$(N*1E6 )+"μ":RETURN
2050 IF ABS(N)<1 THEN RESULT$=STR$(N*1E3 )+"m":RETURN
2060 IF ABS(N)<1E3 THEN RESULT$=STR$(N ) :RETURN
2070 IF ABS(N)<1E6 THEN RESULT$=STR$(N*1E-3)+"k":RETURN
2080 IF ABS(N)<1E9 THEN RESULT$=STR$(N*1E-6)+"M":RETURN
2090 IF ABS(N)<1E12 THEN RESULT$=STR$(N*1E-9)+"G":RETURN
2100 RESULT$=STR$(N*1E-12)+"T":ERR=1:RETURN
CLS:RUN
画面1、抵抗値Rと静電容量Cからカットオフ周波数fcを計算するツール

抵抗値Rと静電容量Cから、CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcを計算します。実行例1を参考にして、RCの値を入力してください。

数値の入力の後にはENTERキーを押します。

Rの値については2Ωの場合は2、2kΩの場合は2k、2MΩの場合は2M(Mは大文字)と入力してください。

Cの値については3Fの場合は3、3mFの場合は3m(mは小文字)、3μFの場合はまたは3u(Uの小文字)、3nFの場合は3n、3pFの場合は3pと入力してください。

2k3mなどと補助単位を使わずに、2E3(2×103の意味)や3E-3(3×10-3の意味)などと指数形式で入力する事もできます。

なおこのツールは、Syn BASICを使って動作しています。

実行例1に、抵抗値Rを1kΩ、静電容量Cを0.1μFとして、カットオフ周波数fcを計算した時の画面表示の例を示します。

抵抗値Rと静電容量Cから、CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcを計算します。RとCの値を入力してください。
    
R[Ω]: 1k ← 1kΩを入力
C[F]: 0.1u ← 0.1μFを入力

入力されたR: 1kΩ
入力されたC : 100nF 注:100nFは0.1μFと同じ値
fcの計算結果: 1.59154943092kHz ← 計算結果

抵抗値Rと静電容量Cから、CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcを計算します。RとCの値を入力してください。

R[Ω]:  ← 次の計算のための抵抗値の入力
    
実行例1、Rに1kΩ、Cに0.1μFを入力した場合のfcの計算例

画面1のツールで、Rに1kΩ、Cに0.1μFを入力した場合の計算例を示します。

5.1次CRローパスフィルタ・ハイパスフィルタを設計するツール

図2に示す1次CRハイパスフィルタ、あるいは図3に示す1次CRローパスフィルタのカットオフ周波数fcが決まっていて、そのカットオフ周波数を実現する様に、抵抗値Rや静電容量Cを決定する場合を考えます。

図2(再掲)、1次CRハイパスフィルタの回路図
図2(再掲)、1次CRハイパスフィルタの回路図
図3(再掲)、1次CRローパスフィルタの回路図
図3(再掲)、1次CRローパスフィルタの回路図

最初にRの値を決めて、次にそのRの値で目標のカットオフ周波数が得られる様にCの値を計算するには、式(2)を使います。

C=1Rfc ・・・ (2)

あるいは、最初にCの値を決めて、次にそのCの値で目標のカットオフ周波数が得られるようにRの値を計算するには、式(3)を使います。

R=1Cfc ・・・ (3)

最初にRを決めて、Cの値を計算するには、画面2のツールが利用できます。

あるいは、最初にCを決めて、Rの値を計算するには、画面3のツールが利用できます。

これらのツールを使う場合は、まず画面をクリックしてから数値を入力してください。数値にはkやMなどの補助単位が使えます。

実行例2に、カットオフ周波数fcを20kHz、抵抗値Rを1.2kΩとして、静電容量Cを計算した時の画面表示の例を示します。

実行例3に、カットオフ周波数fcを10kHz、静電容量Cを4700pFとして、抵抗値Rを計算した時の画面表示の例を示します。

10 PI=3.141592653589793238
20 PRINT "CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと抵抗値Rから、静電容量Cを計算します。fcとRの値を入力してください。"
30 PRINT
40 INPUT "fc[Hz]: ",S$
50 GOSUB 1000
60 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 40
70 FC=RESULT
80 INPUT "R[Ω]: ",S$
90 GOSUB 1000
100 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 80
110 R=RESULT
120 PRINT
130 N=FC:GOSUB 2000
140 PRINT "入力されたfc: ";RESULT$;"Hz"
150 N=R:GOSUB 2000
160 PRINT "入力されたR: ";RESULT$;"Ω"
170 C=1/(2*PI*R*FC)
180 N=C:GOSUB 2000
190 PRINT "Cの計算結果: ";RESULT$;"F"
200 PRINT
210 GOTO 20
1000 '入力した文字列を数値に変換
1010 IF S$="" THEN ERR=1:RETURN
1020 IF LEFT$(S$,1)="+" THEN S$=MID$(S$,2)
1030 IF S$="" THEN ERR=1:RETURN
1040 L$=RIGHT$(S$,1)
1050 IF L$="K" OR L$="k" THEN K=1E3 :GOTO 1160
1060 IF L$="M" THEN K=1E6 :GOTO 1160
1070 IF L$="G" OR L$="g" THEN K=1E9 :GOTO 1160
1080 IF L$="T" OR L$="t" THEN K=1E12 :GOTO 1160
1090 IF L$="m" THEN K=1E-3 :GOTO 1160
1100 IF L$="μ" OR L$="u" THEN K=1E-6 :GOTO 1160
1110 IF L$="n" OR L$="N" THEN K=1E-9 :GOTO 1160
1120 IF L$="p" OR L$="P" THEN K=1E-12:GOTO 1160
1130 IF L$="f" OR L$="F" THEN K=1E-15:GOTO 1160
1140 K=1
1150 GOTO 1170
1160 S$=LEFT$(S$,LEN(S$)-1)
1170 IF S$="" THEN ERR=1:RETURN
1180 STAT=0
1190 FOR I=1 TO LEN(S$)
1200 C$=MID$(S$,I,1)
1210 IF STAT=0 THEN IF C$="." THEN STAT=1:GOTO 1310
1220 IF STAT=0 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1230 IF STAT=0 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1240 IF STAT=1 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=2:GOTO 1310
1250 IF STAT=2 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1260 IF STAT=2 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1270 IF STAT=3 THEN IF C$="+" OR C$="-" THEN STAT=4:GOTO 1310
1280 IF STAT=3 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1290 IF STAT=4 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1300 IF STAT=5 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1310 NEXT I
1320 IF (STAT=1)+(STAT=3)+(STAT=4) THEN ERR=1:RETURN
1330 RESULT=VAL(S$)*K
1340 IF RESULT<=1E-20 THEN ERR=1:RETURN
1350 ERR=0:RETURN
2000 '数値を補助単位付きの文字列に変換
2010 IF ABS(N)<1E-12 THEN RESULT$=STR$(N*1E15)+"f":RETURN
2020 IF ABS(N)<1E-9 THEN RESULT$=STR$(N*1E12)+"p":RETURN
2030 IF ABS(N)<1E-6 THEN RESULT$=STR$(N*1E9 )+"n":RETURN
2040 IF ABS(N)<1E-3 THEN RESULT$=STR$(N*1E6 )+"μ":RETURN
2050 IF ABS(N)<1 THEN RESULT$=STR$(N*1E3 )+"m":RETURN
2060 IF ABS(N)<1E3 THEN RESULT$=STR$(N ) :RETURN
2070 IF ABS(N)<1E6 THEN RESULT$=STR$(N*1E-3)+"k":RETURN
2080 IF ABS(N)<1E9 THEN RESULT$=STR$(N*1E-6)+"M":RETURN
2090 IF ABS(N)<1E12 THEN RESULT$=STR$(N*1E-9)+"G":RETURN
2100 RESULT$=STR$(N*1E-12)+"T":ERR=1:RETURN
CLS:RUN
画面2、カットオフ周波数fcと抵抗値Rから静電容量Cを計算するツール

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと抵抗値Rから、静電容量Cを計算します。実行例2を参考にして、fcRの値を入力してください。

数値の入力の後にはENTERキーを押します。

fcの値については2Hzの場合は2、2kHzの場合は2k、2MHzの場合は2M(Mは大文字)と入力してください。

Rの値については3Ωの場合は3、3kΩの場合は3k、3MΩの場合は3M(Mは大文字)と入力してください。

2k3Mなどと補助単位を使わずに、2E3(2×103の意味)や3E6(3×106の意味)などと指数形式で入力する事もできます。

なおこのツールは、Syn BASICを使って動作しています。

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと抵抗値Rから、静電容量Cを計算します。fcとRの値を入力してください。

fc[Hz]: 20k ← 20kHzを入力
R[Ω]: 1.2k ← 1kΩを入力

入力されたfc: 20kHz
入力されたR : 1.2kΩ
Cの計算結果: 6.63145596216nF ← 計算結果

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと抵抗値Rから、静電容量Cを計算します。fcとRの値を入力してください。

fc[Hz]:  ← 次の計算のためのカットオフ周波数の入力
    
実行例2、fcに20kHz、Rに1.2kΩを入力した場合のCの計算例

画面2のツールで、fcに20kHz、Rに1.2kΩを入力した場合の計算例を示します。

広告
10 PI=3.141592653589793238
20 PRINT "CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと静電容量Cから、抵抗値Rを計算します。fcとCの値を入力してください。"
30 PRINT
40 INPUT "fc[Hz]: ",S$
50 GOSUB 1000
60 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 40
70 FC=RESULT
80 INPUT "C[F]: ",S$
90 GOSUB 1000
100 IF ERR THEN PRINT "正の値を正しく入力してください。":GOTO 80
110 C=RESULT
120 PRINT
130 N=FC:GOSUB 2000
140 PRINT "入力されたfc: ";RESULT$;"Hz"
150 N=C:GOSUB 2000
160 PRINT "入力されたC: ";RESULT$;"F"
170 R=1/(2*PI*C*FC)
180 N=R:GOSUB 2000
190 PRINT "Rの計算結果: ";RESULT$;"Ω"
200 PRINT
210 GOTO 20
1000 '入力した文字列を数値に変換
1010 IF S$="" THEN ERR=1:RETURN
1020 IF LEFT$(S$,1)="+" THEN S$=MID$(S$,2)
1030 IF S$="" THEN ERR=1:RETURN
1040 L$=RIGHT$(S$,1)
1050 IF L$="K" OR L$="k" THEN K=1E3 :GOTO 1160
1060 IF L$="M" THEN K=1E6 :GOTO 1160
1070 IF L$="G" OR L$="g" THEN K=1E9 :GOTO 1160
1080 IF L$="T" OR L$="t" THEN K=1E12 :GOTO 1160
1090 IF L$="m" THEN K=1E-3 :GOTO 1160
1100 IF L$="μ" OR L$="u" THEN K=1E-6 :GOTO 1160
1110 IF L$="n" OR L$="N" THEN K=1E-9 :GOTO 1160
1120 IF L$="p" OR L$="P" THEN K=1E-12:GOTO 1160
1130 IF L$="f" OR L$="F" THEN K=1E-15:GOTO 1160
1140 K=1
1150 GOTO 1170
1160 S$=LEFT$(S$,LEN(S$)-1)
1170 IF S$="" THEN ERR=1:RETURN
1180 STAT=0
1190 FOR I=1 TO LEN(S$)
1200 C$=MID$(S$,I,1)
1210 IF STAT=0 THEN IF C$="." THEN STAT=1:GOTO 1310
1220 IF STAT=0 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1230 IF STAT=0 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1240 IF STAT=1 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=2:GOTO 1310
1250 IF STAT=2 THEN IF C$="e" OR C$="E" THEN STAT=3:GOTO 1310
1260 IF STAT=2 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1270 IF STAT=3 THEN IF C$="+" OR C$="-" THEN STAT=4:GOTO 1310
1280 IF STAT=3 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1290 IF STAT=4 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN ELSE STAT=5:GOTO 1310
1300 IF STAT=5 THEN IF C$<"0" OR C$>"9" THEN ERR=1:RETURN
1310 NEXT I
1320 IF (STAT=1)+(STAT=3)+(STAT=4) THEN ERR=1:RETURN
1330 RESULT=VAL(S$)*K
1340 IF RESULT<=1E-20 THEN ERR=1:RETURN
1350 ERR=0:RETURN
2000 '数値を補助単位付きの文字列に変換
2010 IF ABS(N)<1E-12 THEN RESULT$=STR$(N*1E15)+"f":RETURN
2020 IF ABS(N)<1E-9 THEN RESULT$=STR$(N*1E12)+"p":RETURN
2030 IF ABS(N)<1E-6 THEN RESULT$=STR$(N*1E9 )+"n":RETURN
2040 IF ABS(N)<1E-3 THEN RESULT$=STR$(N*1E6 )+"μ":RETURN
2050 IF ABS(N)<1 THEN RESULT$=STR$(N*1E3 )+"m":RETURN
2060 IF ABS(N)<1E3 THEN RESULT$=STR$(N ) :RETURN
2070 IF ABS(N)<1E6 THEN RESULT$=STR$(N*1E-3)+"k":RETURN
2080 IF ABS(N)<1E9 THEN RESULT$=STR$(N*1E-6)+"M":RETURN
2090 IF ABS(N)<1E12 THEN RESULT$=STR$(N*1E-9)+"G":RETURN
2100 RESULT$=STR$(N*1E-12)+"T":ERR=1:RETURN
CLS:RUN
画面3、カットオフ周波数fcと静電容量Cから抵抗値Rを計算するツール

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと静電容量Cから、抵抗値Rを計算します。実行例3を参考にして、fcCの値を入力してください。

数値の入力の後にはENTERキーを押します。

fcの値については2Hzの場合は2、2kHzの場合は2k、2MHzの場合は2M(Mは大文字)と入力してください。

Cの値については3Fの場合は3、3mFの場合は3m(mは小文字)、3μFの場合はまたは3u(Uの小文字)、3nFの場合は3n、3pFの場合は3pと入力してください。

2k3mなどと補助単位を使わずに、2E3(2×103の意味)や3E-3(3×10-3の意味)などと指数形式で入力する事もできます。

なおこのツールは、Syn BASICを使って動作しています。

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと静電容量Cから、抵抗値Rを計算します。fcとCの値を入力してください。

fc[Hz]: 10k ← 10kHzを入力
C[F]: 4700p ← 4700pFを入力

入力されたfc: 10kHz
入力されたC : 4.7nF 注:4.7nFは4700pFと同じ値
Rの計算結果: 3.38627538493kΩ ← 計算結果

CR型1次ローパスフィルタ(またはハイパスフィルタ)のカットオフ周波数fcと静電容量Cから、抵抗値Rを計算します。fcとCの値を入力してください。

fc[Hz]:  ← 次の計算のためのカットオフ周波数の入力
    
実行例3、fcに10kHz、Cに4700pFを入力した場合のRの計算例

画面3のツールで、fcに10kHz、Rに4700pFを入力した場合の計算例を示します。

関連用語

関連ページ

Arduino 電子工作
このサイトの記事が本になりました。
書名:Arduino 電子工作
ISBN:978-4-7775-1941-5
工学社の書籍の内容の紹介ページ
本のカバーの写真か書名をクリックすると、Amazonの書籍購入ページに移動します。
こちらのページもおすすめです。